// Coin.pov

#include "textures.inc"
#include "colors.inc"

camera {
   location y - x
   look_at 0
}

light_source { 2*y color White }

#declare coin = intersection {
   union {
      height_field {
         tga "tashal1.tga"
         smooth
         translate -.5*(x+z)
         clipped_by { cylinder { -y, 2*y, .49 } }
         rotate 180*x
         scale <1,.02,1>
         translate .02*y
      }
      height_field {
         tga "tashal2.tga"
         smooth
         translate -.5*(x+z)
         clipped_by { cylinder { -y, 2*y, .49 } }
         inverse
         scale <1,.02,1>
         translate -.02*y
      }
      difference {
         cylinder { -.02*y, .02*y, .48 }
         cylinder { -.03*y, .03*y, .475 }
         texture { Silver1 normal { dents 1 } }
      }
      texture {
         pigment { Silver1_Colour }
         finish {
            metallic 2
            ambient 0.25
            diffuse 0.65
            reflection 0.45
            brilliance 10
            phong 1
         }
      }
   }
   box {
      0, .05
      translate -.025*x
      inverse
      scale 1 + 20*x
      rotate 180*z
      rotate 45*x
      rotate -6*y
      translate -.0*z
   }
   box {
      0, .05
      translate -.025*x
      inverse
      scale 1 + 20*x
      rotate 180*z
      rotate 45*x
      rotate -92*y
      translate -.01*x
   }
   texture {
      pigment { Silver1_Colour }
      normal { dents .3 scale .01 }
      finish {
         metallic 1
         ambient 0.5
         reflection 0.5
         brilliance 10
         phong 1
      }
   }
}

object {
   coin
   rotate 2*clock*x
   rotate clock*y
}